### System details

AMD Ryzen 7 5800X, NVIDIA GTX 1070, Omarchy 4.0.0, quickshell-git 0.3.0.r20.g28771c7, qt6-declarative 6.11.1

### What's wrong?

An open `qs.Ui.Dropdown` clips its last option and makes the list scrollable, even with two options.

`shell/Ui/Dropdown.qml` sizes the popup from its rows, then assigns padding on top of that height:

```qml
implicitHeight: Math.min(root.options.length * root.popupRowHeight + Math.max(0, root.options.length - 1) * Style.spacing.labelGap + Style.spacing.xxs,
                         root.popupRowHeight * 8 + 7 * Style.spacing.labelGap + Style.spacing.xxs)
padding: Style.spacing.hairline
topPadding: Border.top(root.popupBorderSpec) + Style.spacing.hairline
bottomPadding: Border.bottom(root.popupBorderSpec) + Style.spacing.hairline
```

`Popup.implicitHeight` is the outer height, so the content item gets `height - topPadding - bottomPadding`. The formula reserves `Style.spacing.xxs` (2px) for that, while the padding is `2 * (popupBorderWidth + hairline)`. The content area is short by `2 * popupBorderWidth`, for any option count and row height.

To reproduce, on a theme with a 2px popup border:

```qml
import QtQuick
import Quickshell
import qs.Ui

ShellRoot {
  FloatingWindow {
    implicitWidth: 520; implicitHeight: 300
    Dropdown {
      id: probe
      x: 60; y: 40; width: 320
      options: [{ value: "a", label: "Google" }, { value: "b", label: "LibreTranslate" }]
      value: "a"
      Component.onCompleted: Qt.callLater(function() { probe.open() })
    }
  }
}
```

The popup comes out 62px tall: 2px border, 1px padding, 28px row, 29px left for a 4px gap plus a 28px row, 1px padding, 2px border. It needs 66px. In the screenshot the shipped dropdown is on the left, the patched one on the right.

In-tree this is visible in the dev gallery, `shell/plugins/dev-gallery/GalleryPanel.qml:1581`.

Fix:

```diff
-        implicitHeight: Math.min(root.options.length * root.popupRowHeight + Math.max(0, root.options.length - 1) * Style.spacing.labelGap + Style.spacing.xxs,
-                                 root.popupRowHeight * 8 + 7 * Style.spacing.labelGap + Style.spacing.xxs)
+        implicitHeight: Math.min(root.options.length * root.popupRowHeight + Math.max(0, root.options.length - 1) * Style.spacing.labelGap,
+                                 root.popupRowHeight * 8 + 7 * Style.spacing.labelGap)
+                        + topPadding + bottomPadding
```

I can send this as a PR if it's welcome.