## What happened

`~/.config/omarchy/shell.json` hot-reloads on save, and `omarchy-shell idle status` immediately reports the new `idle.screensaver` / `idle.lock` values. But idle detection stops working **entirely** — no screensaver, no lock, no display blanking — until `omarchy restart shell`.

It fails silently. The status output looks correct, so there is no indication anything is wrong. My machine sat unlocked for ~21 hours before I noticed, with a matching 21-hour gap in the `omarchy idle` journal lines (the last entry was `idle-monitor: active`, and no further transition ever came).

## Expected

Either the new timeouts take effect on save, or the shell makes it clear they have not been applied.

## Root cause

`shell/plugins/services/idle/Service.qml`:

```qml
IdleMonitor {
  id: idleMonitor
  enabled: root.idleEnabled
  timeout: root.firstIdleTimeoutSeconds
  respectInhibitors: true
  onIsIdleChanged: root.handleIdleChanged()
}
```

Quickshell's `IdleMonitor` does not re-arm its `ext-idle-notification` when `timeout` changes at runtime. Because `firstIdleTimeoutSeconds` is `Math.min(screensaverTimeoutSeconds, lockTimeoutSeconds)`, **any** edit to those two values in `shell.json` mutates `timeout` on a live monitor, and the monitor then goes permanently silent.

## Reproduction

Standalone, no Omarchy involved — `quickshell -n -p .` on this file:

```qml
import QtQuick
import Quickshell
import Quickshell.Wayland

ShellRoot {
  id: root
  property int t: 3600
  IdleMonitor {
    enabled: true
    timeout: root.t
    respectInhibitors: true
    onIsIdleChanged: console.log("isIdle=" + isIdle + " timeout=" + timeout)
  }
  Timer {
    interval: 5000; running: true; repeat: false
    onTriggered: root.t = 8      // change timeout on a live monitor
  }
}
```

Leave the machine untouched. The monitor never reports idle. A control `IdleMonitor` *constructed* with `timeout: 8` reports idle after 8s as expected.

## Validated workaround / suggested fix

Pulsing `enabled` off and back on re-arms the notification — but only if the pulse spans an event-loop turn. `Qt.callLater` is **not** enough (I tested it; still never fires). A short `Timer` works:

```qml
Timer { id: rearm; interval: 150; repeat: false; onTriggered: root.en = true }

onFirstIdleTimeoutSecondsChanged: { root.en = false; rearm.restart() }
```

With that in place the same probe logs `isIdle=true timeout=8` on schedule.

This may warrant an upstream Quickshell fix as well, but the pulse is a small, self-contained change on the Omarchy side.

## Impact

Editing `shell.json` is the documented way to change lock timing, and doing it silently disables auto-lock until the shell happens to be restarted. That seems worth treating as security-relevant rather than cosmetic.

## System

- Omarchy `4.0.0-1`
- Hyprland `0.56.2-1`
- `quickshell-git 0.3.0.r20.g28771c7-1`
- AMD Ryzen AI MAX+ 395 w/ Radeon 8060S (Strix Halo)