## System details

- Intel MacBook Pro, Core i9-9880H
- Intel UHD Graphics 630 and AMD Radeon Pro 5500M
- Omarchy `4.0.3-1`
- Quickshell `0.3.1-1`
- Hyprland `0.56.2-2`
- Omalaunch `v0.4.0`, commit `59b7ecd`

## Failure

The new plugin API gives a valid third-party menu `appLibrary: null` after its manifest passes through the panel `Instantiator`. The installed application list and application search are empty. Static menu commands still work. The stock first-party menu displays applications correctly on the same machine.

This was first reported at https://github.com/DanielLemky/omalaunch/issues/68. I reproduced it on a second machine with the same package versions.

## Reproduction

1. Use Omarchy 4.0.3 and Quickshell 0.3.1.
2. Install and enable Omalaunch v0.4.0. Its manifest declares `"kinds": ["menu", "bar-widget"]`.
3. Open its Apps submenu or search for an installed application.
4. Disable Omalaunch and enable `omarchy.menu` for comparison.

Expected: the third-party menu receives the app-library API promised to plugins with the `menu` kind.

Actual: its injected `PluginShellApi` has the correct plugin ID, but `appLibrary` is null. The stock menu works because it receives the full shell, not this API.

## Confirmed cause

In `shell/shell.qml`:

1. `computePanelEntries()` puts registry manifests in the panel model.
2. `Instantiator` converts the nested `kinds` array to a QML `V4Sequence`.
3. The loader calls `pluginShellFor(panelEntry.manifest)` with that converted value.
4. `manifestHasKind()` requires `Array.isArray(manifest.kinds)`. This returns false for the sequence, although `kinds.indexOf("menu")` returns 0.
5. `createScopedPluginShell()` therefore creates an API without app-library access.

A previous lookup with the original registry manifest can first create a valid menu API. The delegate lookup then changes the capability profile to `no-menu`, which revokes that API and replaces it.

The plugin's separately injected public manifest looks correct because `publicPluginManifest()` copies it through JSON. That converts the sequence back to an array, but it is too late for the capability check.

The following small test reproduces the conversion without a desktop window or Omalaunch. Save it as `shell.qml` and run `QT_QPA_PLATFORM=offscreen quickshell -p shell.qml`:

```qml
import QtQuick
import QtQml.Models
import Quickshell

ShellRoot {
  id: root
  property var manifest: ({ id: "example.menu", kinds: ["menu"] })
  property var entries: [{ manifest: root.manifest }]

  Instantiator {
    model: root.entries
    delegate: QtObject {
      required property var modelData
      Component.onCompleted: {
        var kinds = modelData.manifest.kinds
        console.log("delegate", Array.isArray(kinds),
          Object.prototype.toString.call(kinds), kinds.indexOf("menu"))
      }
    }
  }

  Component.onCompleted: {
    console.log("registry", Array.isArray(manifest.kinds))
    Qt.callLater(Qt.quit)
  }
}
```

Output on Quickshell 0.3.1:

```text
delegate false [object V4Sequence] 0
registry true
```

## Tested correction

Resolve the plugin ID to the registry's validated manifest inside `pluginShellFor()`, before the trust and capability checks. Do not use the delegate's converted manifest for those decisions:

```qml
function pluginShellFor(manifest) {
  var key = String(manifest && manifest.id || "")
  if (!key) return null
  var registeredManifest = shell.pluginRegistry.installedPlugins[key]
  if (!registeredManifest) return null
  if (registeredManifest.__isFirstParty) return shell
  return shell.createScopedPluginShell(registeredManifest, key, true,
    shell.pluginHasBarCapabilities(registeredManifest))
}
```

I tested this correction in a separate copy of the packaged 4.0.3 shell, with clean Omalaunch v0.4.0. Installed applications appeared. Search from Apps and from the root menu worked. Selecting Alacritty opened a new Alacritty window. Reopening the menu and rescanning plugins retained application access.

An earlier diagnostic test returned 98 application rows after the type check was corrected. The original path returned zero rows because the library was null.

No packaged files were edited. The standard shell and plugin were restored after testing. Screenshots and a private `omarchy debug --no-sudo --print` log were collected; the complete system log is not included because it contains unrelated machine details.

## Scope

`AppLibrary.qml`, `AppSearch.js`, and the stock menu QML did not change between v4.0.2 and v4.0.3. The relevant change is the new third-party API injection from #9618, included in the 4.0.3 backport #10733.

This is separate from Omalaunch's use of the raw-only `iconIndexChanged` signal. Correcting the app-library grant restores applications without changing Omalaunch. The icon-refresh compatibility change is being handled separately in Omalaunch.